Mac version of ScanTags now available (with any luck)

steve harley pdml at paper-ape.com
Sun Oct 11 20:46:39 EDT 2009


On 2009-10-11 12:39 , John Francis wrote:
> On Sun, Oct 11, 2009 at 07:25:25PM +1300, David Mann wrote:
>>
>> Works well but I can't drag&  drop onto its icon.  Not a big issue, I
>> can just open a terminal.
> [...]
> Maybe one of the resident mac experts can suggest something?

to begin with note that most of the same information (except the actual 
lens name and the ISO setting) is available from a simple Get Info 
(command-i) on the Mac

anyhow, to get a command-line tool to do drag & drop, one can use a few 
lines of AppleScript as a wrapper; rather than hard-code the location of 
the ScanTags executable into the script, i assume ScanTags has been 
embedded into the application package; instructions to assemble this 
AppleScript/ScanTags package follow

(John, i can send you a zip of this all assembled if you'd like to host it)

save the script:

- launch Script Editor, an empty "Untitled" window should open
- paste the script lines below into the window
- choose Save from the File menu
- under File format choose "Application bundle"
- enter a name, e.g. macScanTags, and save it somewhere

embed ScanTags:

- find the macScanTags application you saved in Finder
- right- or control-click on the file and choose "Show Package Contents"
- a new window will open up with a directory that contains a 
subdirectory "Contents", open that directory and open its subdirectory 
"Resources"
- place the ScanTags executable file into Resources
- close the Finder window
- try dragging an image file (or files) on the macScanTags application file

here's the script (any line that's not indented is overflow, and should 
be merged with the previous line):

   on open (some_files) -- if launched by dropping file(s)
     set app_path to quoted form of POSIX path of (path to me)
     -- path to ScanTags embedded in application bundle
     set tool_path to app_path & "Contents/Resources/ScanTags "
     -- clean up command line output
     set output_filter to " | grep \"^  \""
     repeat with a_file in some_files
       set the_path to quoted form of POSIX path of a_file
       set the_cmd to tool_path & the_path & output_filter
       set the_info to do shell script the_cmd
       display dialog (a_file as text) & return & return & the_info
     end repeat
   end open

   on run -- if launched without dropping file(s)
     choose file with prompt "choose image file(s)" with multiple 
selections allowed
     open (the result as list)
   end run





More information about the PDML mailing list